home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio / Ham Radio CD-ROM (Emerald Software) (1995).ISO / misc / utilitys / trops.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1980-01-01  |  2.3 KB  |  63 lines
  1. 10  REM MIKE MOREKEN 2-84
  2. 15  PI=3.1416
  3. 20  R=6371.4:REM 1 KM=.62137  MILES:R=EARTH RADIUS IN KM
  4. 30  PRINTCHR$(26);:PRINT:PRINTTAB(15);"THIS PROGRAM CALCULATES THE TOTAL LOSS FOR RECEPTION"
  5. 40  PRINT"OF TROPOSCATTER COMMUNICATIONS.  PLEASE ENTER THE REQUIRED VALUES"
  6. 50  PRINT"TO OBTAIN THE TOTAL SCATTERING LOSS.  FOR CORRECT NUMERICAL RESULTS,"
  7. 60  PRINT"PLEASE ENTER THE FREQUENCY IN MHz AND ALL ANGLES IN DEGREES "
  8. 70  PRINT:INPUT"DO YOU WISH TO USE THE ENGLISH OR METRIC SYSTEM (E/M)";A$
  9. 80  IF A$="M" THEN Q$=" IN METERS" 
  10. 90  IF A$="M" THEN R$=" IN KILOMETERS" 
  11. 100  IF A$="E" THEN Q$=" IN FEET"
  12. 110  IF A$="E" THEN R$=" IN MILES"
  13. 120  REM**********TX****************
  14. 130  INPUT"IS THERE AN OBSTRUCTION BETWEEN THE TX AND HORIZON (Y/N)";O$
  15. 140  IF O$="N" THEN AA=0:IF AA=0 THEN 240
  16. 150  PRINT"WHAT IS THE TX HEIGHT";Q$:INPUT T1
  17. 160  IF T1<0 THEN 150
  18. 170  PRINT "WHAT IS THE HEIGHT OF THE TX OBSTRUCTION";Q$:INPUT T2
  19. 180  IF T2 <0 THEN 170
  20. 190  IF T2<T1 THEN PRINT"YOU HAVE ENTERED A NEGATIVE HORIZON"
  21. 200  PRINT"WHAT IS THE DISTANCE BETWEEN THE TX & OBSTRUCTION";R$:INPUT D1
  22. 210  IF D1<=0 THEN 200
  23. 220  REM*********RX******************
  24. 230  PRINTCHR$(26);
  25. 240  INPUT"IS THERE AN OBSTRUCTION BETWEEN THE RX AND HORIZON (Y/N)";P$
  26. 250  IF P$="N" THEN AB=0:IF AB=0 THEN 330
  27. 260  PRINT:PRINT"NOW THE RECEIVING END":PRINT"WHAT IS THE RX HEIGHT";Q$:INPUT T3
  28. 270  IF T3<0 THEN 190
  29. 280  PRINT"HEIGHT OF THE OBSTRUCTION IN PATH OF RX";Q$:INPUT T4
  30. 290  IF T4<0 THEN 280
  31. 300  PRINT"WHAT IS THE DISTANCE BETWEEN THIS OBSTRUCTION & THE RX";R$
  32. 310  INPUT D2
  33. 320  IF D2<=0 THEN 300
  34. 330  PRINT"WHAT IS THE DISTANCE BETWEEN THE RX & TX";R$:INPUT D3
  35. 340  IF (D1+D2)>D3 THEN 330
  36. 350  INPUT"WHAT IS THE FREQUENCY IN MHz";F
  37. 360  INPUT"WHAT IS THE BEAMWIDTH OF THE RX ANTENNA IN DEGREES";BR
  38. 370  INPUT"WHAT IS THE BEAMWIDTH OF THE TX ANTENNA IN DEGREES";BT
  39. 380  PRINT"THE REFRACTIVE INDEX TYPICALLY VARIES BETWEEN 250 & 400"
  40. 390  INPUT"WHAT IS THE REFRACTIVE INDEX";N
  41. 400  IF N<100 OR N>500 THEN 380
  42. 410  IF A$="M" THEN K=1 ELSE K=0.3048
  43. 420  T1=K*T1:T2=K*T2:T3=K*T3:T4=K*T4
  44. 430  IF A$="M" THEN L=1 ELSE L=1.6093
  45. 440  D1=L*D1:D2=L*D2:D3=L*D3
  46. 450  IF D1=0 THEN 480
  47. 460  A5=(T2-T1)/(1000*D1):A6=D1/(2*R)
  48. 470  AA=(A5-A6)*(180/PI)
  49. 480  IF D2=0 THEN 510
  50. 490  B5=(T4-T3)/(1000*D2):B6=D2/(2*R)
  51. 500  AB=(B5-B6)*(180/PI)
  52. 510  AC=(D3/R)*(180/PI)
  53. 520  AS=AC+AA+AB
  54. 530  FS=32.5+(20*LOG(D3)/LOG(10))+(20*LOG(F)/LOG(10))
  55. 540  SC=21+10*AS+10*LOG(F)/LOG(10)
  56. 550  AO=(2*AS/((BR*BT)^0.5)):AP=AO+2
  57. 560  RI=0.2*(310-N)
  58. 570  TL=55.5+20*LOG(D3)/LOG(10)+30*LOG(F)/LOG(10)+AO+RI
  59. 580  PRINTCHR$(26);
  60. 590  PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT TAB(22);"THE TOTAL LOSS IS";TL" dB"
  61. 600  PRINT:PRINT:PRINT:PRINT:PRINT:INPUT "WANT TO TRY AGAIN (Y/N)";Y$:IF Y$="Y" THEN 10
  62. 610  END
  63.